HP-71 Math Pac Manual



#2

Hello,

Anybody has a copy or file available of the HP-71B Math Pack? Will appreciate your letting me know.

Thanks, ÁM.


#3

Mientras lo consigues, espero que esto te pueda servir. Saludos de V.

==============================================================================
# GUIA DE CONSULTA RAPIDA DE OPERACIONES COMPLEJAS Y MATRICIALES DE LA HP-71 #
==============================================================================
------------------------------------------------------------------------------
| OPERACIONES CON NUMEROS COMPLEJOS |
------------------------------------------------------------------------------

COMPLEX A,B(2),C(3,3)
COMPLEX SHORT C(5,5)

Define y crea en memoria variables, vectores, y matrices complejas, de
precision REAL (12 cifras mantisa, 3 exponente), o SHORT (5 cifras de
mantisa, y 2 de exponente)

IMAGE 2D,C(2D.2D,2D.2D,"i")

Especifica formatos de salida para variables complejas

Todas las funciones que siguen a continuacion funcionan en modo CALC, y
dejan el resultado accesible mediante la funcion RES, como las funciones
normales de la maquina:


Z=(2,3) Asignacion de un valor complejo (2+3i) a una variable
Z=(2,3)+(4,5) Suma de complejos
Z=(2,3)-(4,5) Resta de complejos
Z=(2,3)*(4,5) Multiplicacion de complejos
Z=(2,3)/(4,5) Division de complejos
Z=(2,3)^(4,5) Elevacion de un complejo a la potencia de otro complejo
Z=SQR((2,3)) Raiz cuadrada de un complejo
Z=SIN((2,3)) Seno id.
Z=COS((2,3)) Coseno id.
Z=TAN((2,3)) Tangente id.
Z=SINH((2,3)) Seno hiperbolico id.
Z=COSH((2,3)) Coseno id. id.
Z=TANH((2,3)) Tangente id. id.
Z=EXP((2,3)) exponencial id.
Z=LOG((2,3)) logaritmo id.
R=REPT(Z) Parte real de un complejo
I=IMPT(Z) Parte imaginaria
Z=CONJ(Z) Conjugado de un complejo
Z=ABS(Z) Modulo de un complejo
Z=ARG(Z) Argumento de un complejo
Z=SGN(Z) Vector unitario de un complejo
Z=PROJ(Z) Proyectividad de un complejo
Z=POLAR(Z) Conversion de rectangulares a polares
Z=RECT(Z) Conversion de polares a rectangulares
IF (2,3)=(3,4) Igualdad entre complejos
IF (2,3)#(3,4) Desigualdad entre complejos

-----------------------------------------------------------------------------
| FUNCIONES MATEMATICAS DIVERSAS |
-----------------------------------------------------------------------------

A=SINH(X) Seno hiperbolico
A=COSH(X) Coseno id.
A=TANH(X) Tangente id.
A=ASINH(X) Arcoseno id.
A=ACOSH(X) Arcocoseno id.
A=ATANH(X) Arcotangente id.
A=GAMMA(X) Funcion gamma
A=LOG2(X) Logaritmo en base 2
A$=BSTR$(N,B) Convierte el valor N a la base B (2,8,o 16)
A=BVAL(N$,B) Convierte la string en base B (2,8,16) en su valor base 10
A$=NAN$(N) Da el error contenido en el NaN almacenado en N
N=NEIGHBOR(X,Y) Da el sucesor de X en la direccion de Y
N=SCALE10(X,Y) Multiplica X por 10 elevado a Y
N=IROUND(X) Redondea X segun la OPTION ROUND activa
N=TYPE(X) Da el tipo de la variable X (o X$), que puede ser matricial

-----------------------------------------------------------------------------
| OPERACIONES MATRICIALES |
-----------------------------------------------------------------------------

NOTA: TODAS ESTAS OPERACIONES MATRICIALES FUNCIONAN TAMBIEN CON MATRICES
COMPLEJAS.

DIM A(2),B(3,4)
REAL A(2),B(3,4)
COMPLEX A(2),B(3,4)

Dimensiona (o redimensiona si ya existen) matrices y vectores de
precision REAL (12 cifras mantisa y 3 de exponente).

SHORT A(2),B(3,4)
COMPLEX SHORT A(2),B(3,4)

Dimensiona (o redimensiona, si ya existen), matrices y vectores de
precision corta SHORT (5 cifras de mantisa y 2 de exponente)

INTEGER A(2),B(3,4)

Dimensiona (o redimensiona si existen) matrices y vectores de
precision entera INTEGER (-99999 a +99999)

DESTROY A(2),B(3,4)

Destruye los vectores o matrices especificados, liberando la memoria
que ocupaban

MAT A=ZER Pone a cero la matriz A
MAT A=IDN Convierte la matriz A en una matriz identidad
MAT A=CON Pone todos los elementos de A iguales a 1
MAT A=(X) Pone todos los elementos de A iguales a X
MAT A=B Hace la matriz A igual a la B
MAT A=-B Cambia el signo de la matriz
MAT A=TRN(B) Hace la matriz A igual a la traspuesta de B
MAT A=B+C Suma de matrices
MAT A=B-C Resta de matrices
MAT A=B*C Multiplicacion matricial
MAT A=(X)*C Multiplica todos los elementos por un numero
MAT A=TRN(B)*C Multiplica la traspuesta de B por C
MAT A=INV(B) Inversa de una matriz
MAT X=SYS(A,B) Resuelve los sistemas de ecuaciones de matriz A y
terminos independientes B, y pone el resultado en X
MAT INPUT A,B Pide los elementos de una serie de matrices
MAT DISP A,B Muestra en pantalla una serie de matrices
MAT DISP USING 1000;A,B Lo mismo, pero utilizando un formato
MAT PRINT A,B Imprime los elementos de una serie de matrices
MAT PRINT USING 1000;A,B Lo mismo, pero utilizando un formato
X=DET(A) Calcula el determinante de una matriz
X=DOT(A,B) Calcula el producto vectorial de dos vectores
X=RNORM(A) Calcula la norma por filas (suma de elementos)
X=CNORM(A) Calcula la norma por columnas (id)
X=FNORM(A) Calcula la norma euclidiana (raiz cuadrada de la
suma de los cuadrados de los elementos)
X=UBOUND(A,1) Subindice superior de la matriz en la dimension 1
X=LBOUND(A,2) Subindice inferios de la matriz en la dimension 2

Ejemplo: resolver el sistema de ecuaciones

2*a+b+3*c=6
5*a-b+4*c=8
-3*a+2*b-c=-2

DESTROY ALL @ OPTION BASE 1 @ DIM A(3,3),B(3),X(3)
MAT INPUT A,B
2,1,3,5,-1,4,-3,2,-1,6,8,-2 [ENTER]

MAT X=SYS(A,B) @ FIX 4 @ DELAY 0.5,0.5 @ MAT DISP X

-----------------------------------------------------------------------------
| RAICES E INTEGRALES DE POLINOMIOS Y OTRAS FUNCIONES |
-----------------------------------------------------------------------------

X=FNROOT(A,B,FNF(FVAR))

Calcula la raiz real comprendida entre A y B de la ecuacion FNF(X)=0
dada por el usuario. Si no existe, calcula el minimo de la funcion en
ese intervalo. Se pueden anidar hasta 5 llamadas a FNROOT, pudiendo
asi resolver sistemas de ecuaciones no lineales con hasta 5 incognitas
o bien determinar maximos y minimos de una funcion de hasta 5 variables.

FVAR representa la variable de la funcion,y contiene su valor. Debe
emplearse en la definicion de la ecuacion en lugar de la incognita.
FVALUE es el valor de la funcion en la raiz. Debe ser 0 o casi 0, si es
una raiz. Sino, la X hallada es un minimo de la funcion.
FGUESS es la aproximacion anterior a la raiz

Nota: la ecuacion a resolver puede estar definida:

- en la propia llamada : X=FNROOT(1,2,FVAR^3-FVAR-1)

- en una funcion definida : X=FNROOT(1,2,FNF(FVAR))

donde se supone que existe una funcion definida de una
sola linea o multilinea que define la ecuacion:

10 DEF FNF(X)=X^3-X-1


--------------------------------------------------------------------------

X=INTEGRAL(A,B,P,FNF(IVAR))

Calcula la integral entre A y B de la funcion FNF(X) dada por el usuario
con la precision P. Al terminar, aparte del valor de la integral, se
puede utilizar IBOUND, que da el valor maximo del error cometido. Se pue-
den anidar hasta 5 llamadas a INTEGRAL, lo cual permite calcular inte-
grales multiples de hasta 5 variables.


IBOUND da el valor maximo del error, si es negativo no hubo convergencia
IVAR representa la variable de integracion, y almacena su valor. Debe
emplearse en la definicion de la integral en lugar de la variable
de integracion.
IVALUE es el valor de la ultima integral calculada

Nota: la funcion a integrar puede definirse:

- en la propia llamada : I=INTEGRAL(0,1,1E-5,SIN(IVAR)*COS(IVAR))

- en una funcion definida: I=INTEGRAL(0,1,1E-5,FNF(IVAR))

donde se supone que existe una FNF asi:

10 DEF FNF(X)=SIN(X)*COS(X)


Nota: INTEGRAL puede emplear FNROOT en la definicion de la funcion, y
viceversa, de forma que es posible

- resolver ecuaciones en las que aparecen funciones definidas
por integrales

ej: hallar la x que corresponde a un valor dado de la
probabilidad definida por una campana de Gauss

- integrar funciones implicitas

ej: integrar la funcion definida por X^3+Y^3-3*X*Y=0
(folio de Descartes) entre 0 y 1

-------------------------------------------------------------------------

MAT R=PROOT(P)

Dado el vector P, que contiene los coeficientes de la ecuacion polinomica
de cualquier grado cuyas raices queremos hallar, calcula todas las raices
reales y/o complejas, y las coloca en el vector complejo R.

Ejemplo: Hallar todas las raices de la ecuacion

x^5-3*x^4+8.1*x^2-1.37=0 (5 raices, 6 coeficientes)

DESTROY ALL @ OPTION BASE 1 @ DIM P(6) @ COMPLEX R(5)
MAT INPUT P
P(1)=? 1,-3,0,8.1,0,-1.37 [ENTER]

MAT R=PROOT(P) @ FIX 4 @ DELAY 0.5,0.5 @ MAT DISP R

-----------------------------------------------------------------------------
| SERIES Y TRANSFORMADAS DE FOURIER |
-----------------------------------------------------------------------------

MAT Z=FOUR(B)

Calcula la transformada directa o inversa, o la serie de Fourier de una
serie de datos almacenados en la matriz B, y coloca el resultado en la
matriz Z.


#4

Valentin,

mil gracias por tu pronta y efectiva respuesta. Efectivamente esto me encauza por el buen camino a descubrir este modulo.

Saludos desde la selva negra, AM


#5

Celebro que te sea util, Angel. Aqui te adjunto un par
de ejemplos de elaboracion propia, para que veas mejor
como se usan de forma anidada las potentes funciones "solve" (FNROOT) e "integrate" (INTEGRAL) que este maravilloso ROM proporciona.

Saludos de V.

Ejemplo de integral doble (82 bytes):
-------------------------------------

Calcular la integral doble entre [1,2] y [3,4] de la
funcion z = 1/(X+Y)^2

10 DEF FNF(X,Y)=1/(X+Y)/(X+Y)
20 DEF FNG(X)=INTEGRAL(1,2,.001,FNF(X,IVAR))
30 DISP INTEGRAL(3,4,.001,FNG(IVAR))

RUN -> 4.08219617611E-2

El valor exacto es Ln(25/24) = 4.08219945235E-2. Con
la tolerancia 0.001 hemos obtenido 6-7 cifras correctas.
Este ejemplo tambien podria hacerse directamente desde
el teclado, sin necesidad de lineas de programa.

Ejemplo de resolucion de un sistema de dos ecuaciones
no lineales con dos incognitas (135 bytes)
------------------------------------------------------

Resolver el sistema:

sin(x+y) = x
cos(x-y) = y

1 RADIANS
10 DEF FNF(X,Y)=X-SIN(X+Y)
20 DEF FNG(X,Y)=Y-COS(X-Y)
30 DEF FNY(X)=FNROOT(1,5,FNF(X,FVAR))
40 X=FNROOT(1,5,FNG(FVAR,FNY(FVAR)))
45 Y=FNY(X)
50 FIX 5 @ DISP X;Y

RUN -> 0.93508 0.99802

X-SIN(X+Y) -> 2.00000E-12
Y-COS(X-Y) -> 3.00000E-12

Hemos especificado que las raices se busquen en el
intervalo [1..5], y los valores obtenidos son exactos
hasta 12 cifras (aunque solo mostramos 5). Para otras
ecuaciones o sistemas mas grandes (hasta 5 ecuaciones
simultaneas), se generaliza sin problema.


Possibly Related Threads...
Thread Author Replies Views Last Post
  Need help understanding math.... cyrille de Brébisson 9 447 12-13-2013, 02:23 AM
Last Post: Didier Lachieze
  HP67/97 M.E. Pac cover Ignacio Sánchez 2 217 11-22-2013, 04:04 AM
Last Post: Ignacio Sánchez Reig
  request M.E. pac for HP-67/97 wallet cover scan Ignacio Sánchez 0 153 11-06-2013, 09:36 AM
Last Post: Ignacio Sánchez Reig
  HP-67/97 Mechanical engineering PAC cover Ignacio Sánchez 0 141 10-30-2013, 04:35 AM
Last Post: Ignacio Sánchez Reig
  How to move lexfiles from PC to 71 w/o HP-IL? Joe Horn 9 468 10-18-2013, 03:50 PM
Last Post: Christoph Giesselink
  OT: a math competition site Pier Aiello 0 131 09-16-2013, 06:03 AM
Last Post: Pier Aiello
  HP41 Navigation Pac Perpetual Alminac Dan Pfeiffer 2 197 09-03-2013, 07:39 PM
Last Post: Dan Pfeiffer
  Simple Math Question Namir 2 172 08-09-2013, 06:13 PM
Last Post: Eddie W. Shore
  For sale: HP 25C and Stat Pac 2 for HP 65 Michae Altmann 1 181 04-21-2013, 01:24 PM
Last Post: Raymond Del Tondo
  Cool math clock Bruce Bergman 28 1,103 04-10-2013, 03:13 AM
Last Post: Siegfried (Austria)

Forum Jump: