Super accurate Free42



#4

I tried my old TVM equation in Thomas Okken's Free42 (decimal version) and was surprised it's now more accurate than my real HP42S.

Example 1:

n=63

i=0.00000161

PV=0

PMT=-1,000,000

END Mode (set B/E=0 in Solver)

Solving for FV:

HP 42S: 63,000,031.4434

Free42: 63,000,031.4433

(correct is 63,000,031.4433)

Example 2:

n=31536000

i=10/n

PV=0

PMT=-0.01

END Mode

Solving for FV:

HP 42S: 331,667.006689

Free42: 331,667.006691

(correct is 331,667.006691)

The TVM Solver can be found here:
TVM Solver for HP42S


#5

Free42 carries 25 digits in its reals so it would be disappointing to not gain some accuracy.

- Pauli

#6

Hi Tommi,

I am new here and I wanted to thank you for this excellent version of the TVM. This is the one I will always use from now on. I made a modest contribution to the program, just because I do not have enough memory left in my beloved 42s. Here it is :

00 {78-Byte Prgm }
01 LBL "TVM"
02 MVAR "N"
03 MVAR "I%"
04 MVAR "PV"
05 MVAR "PMT"
06 MVAR "FV"
07 MVAR "B/E"
08 1
09 RCL "I%"
10 %
11 ENTER
12 ENTER
13 ENTER
14 LN1+X
15 RCL* "N"
16 E^X-1
17 RCL* "PMT"
18 RCL ST T
19 1/X
20 RCL+ "B/E"
21 *
22 RCL "PV"
23 RCL ST T
24 LN1+X
25 RCL* "N"
26 E^X
27 *
28 +
29 RCL+ "FV"
30 END

And this is another version if you want to take account of the payments per year (à la 10B):

00 {88-Byte Prgm }
01 LBL "TVM"
02 MVAR "N"
03 MVAR "I%"
04 MVAR "PV"
05 MVAR "PMT"
06 MVAR "FV"
07 MVAR "P/Y"
08 MVAR "B/E"
09 1
10 RCL "I%"
11 %
12 RCL÷ "P/Y"
13 ENTER
14 ENTER
15 ENTER
16 LN1+X
17 RCL* "N"
18 E^X-1
19 RCL* "PMT"
20 RCL ST T
21 1/X
22 RCL+ "B/E"
23 *
24 RCL "PV"
25 RCL ST T
26 LN1+X
27 RCL* "N"
28 E^X
29 *
30 +
31 RCL+ "FV"
32 END

Please try it and tell me if there are "bugs".

Miguel


Edited: 3 Sept 2006, 10:34 p.m.


Possibly Related Threads...
Thread Author Replies Views Last Post
  [HP-PIRME] ^ OPERTOR // => SUPER BUG CompSystems 9 1,880 12-12-2013, 09:26 PM
Last Post: CompSystems
  wp34s (Why it's so accurate) Barry Mead 22 2,158 08-05-2013, 08:51 AM
Last Post: fhub
  The latest version of Free42 is now a OS X Universal application..... zeno333 1 464 10-21-2012, 11:12 PM
Last Post: Matt Agajanian
  I need the last OS X "Universal" version of Free42..... zeno333 0 367 10-13-2012, 04:45 PM
Last Post: zeno333
  [WP34s] Accurate Clock Katie Wasserman 1 418 04-08-2012, 01:25 AM
Last Post: Walter B
  [OT] Free42 on the BlackBerry PlayBook Les Wright 1 447 02-25-2012, 10:56 AM
Last Post: Thomas Okken
  Free42 ? fhub 24 2,115 10-24-2011, 10:06 AM
Last Post: Egan Ford
  Re: Free42 - A Complex glitch? fhub 3 553 09-22-2011, 09:36 PM
Last Post: Thomas Okken
  Re: Free42 - A Complex glitch? Thomas Okken 23 2,106 09-18-2011, 09:10 PM
Last Post: Thomas Okken
  Free42 - A Complex glitch? Ángel Martin 23 2,172 09-14-2011, 09:39 AM
Last Post: Ángel Martin

Forum Jump: