HP-75 Catalog v2

1 DELAY 0 @ I=1

2 A$=CAT$(I) @ IF A$="" THEN I=I-1 @ GOTO 2 ELSE DISP A$

3 B$=WKEY$ @ IF B$="…" THEN I=I+1

4 IF B$="„" THEN I=I-1 @ GOTO 13

5 IF B$='p' THEN C$="Purge" @ GOSUB 15 @ GOTO 16

6 IF B$='e' AND A$[12,12]="B" THEN C$="Edit" @ GOSUB 15 @ GOTO 21

7 IF B$='r' AND A$[12,12]="B" THEN C$="Run" @ GOSUB 15 @ GOTO 22

8 IF B$='c' THEN C$="Copy to card" @ GOSUB 15 @ GOTO 17

9 IF B$='d' THEN C$="Copy to drive" @ GOSUB 15 @ GOTO 19

10 IF B$="b" THEN BYE

11 IF B$='i' THEN C$="Print" @ GOSUB 15 @ GOTO 23

12 GOTO 2

13 IF I=0 THEN I=1

14 GOTO 2

15 A=GETMSG(A$[1,11]&C$&"? [YN]:","yn") @ RETURN

16 IF A=1 THEN PURGE A$ @ GOTO 1 ELSE GOTO 2

17 IF A=1 THEN COPY A$ TO CARD

18 GOTO 2

19 IF A=1 THEN A$=A$[1,POS(A$," ")-1] @ GOTO 30

20 GOTO 2

21 IF A=1 THEN EDIT A$ @ END ELSE GOTO 2

22 IF A=1 THEN RUN A$ ELSE GOTO 2

23 IF A=2 THEN GOTO 2 ELSE B$=CH

R$(27)&"&k" @ A$=A$[1,POS(A$," ")-1]

24 PRINT B$&"1S";TAB((13-LEN(A$))/2);A$;B$&"0S"

25 FOR I=0 TO 99 @ C$=CAT$(I)

26 IF POS(C$,A$)>0 THEN PRINT TAB(6);C$[13,18]&'bytes' @ GOTO 28

27 NEXT I

28 PRINT @ B$=DATE$ @ PRINT TAB(3);B$[7,8]&B$[3,6]&B$[1,2]&"  "&

TIME$ @ PRINT

29 PLIST A$ @ PRINT @ GOTO 2

30 IF A$="keys" THEN COPY KEYS TO A$&":d1" ELSE COPY A$ TO A$&":d1"

31 GOTO 2

p    = Purge File

e    = Edit Basic File

r    = Run Basic File

c    = Copy File to Card

d    = Copy File to Drive ":d1"

i    = Print Basic File

b    = Bye (Off)

Up   = Next File

Down = Previous File 

KEYLEX75 - UNLOCK

	 - SHLOCK

	 - CTLOCK

	 - GETMSG($,$)

	 - GETKEY$($)

	 - WKEY$



Enjoy :-)

Edited: 28 Nov 2011, 6:50 p.m. after one or more responses were posted

What lex file or ROM do I need for the GETMSG function? I tried to enter your program and my 75 does not seem to like that function.

KEYLEX75