It is impressive to see the Lambert W functions included in WP 34s.

However, the W_-1 function give incorrect results. Example:

x e^x = -0.2 has two solutions

-0.259171

-2.542641

On the emulator W(-0.2) correctly returns the first solution.

But W_-1(-0.2), which is expected to give the second solution,

instead returns -0.163746

FYI, W^-1 represents the inverse of W in the WP 34S.

I see. What I thought was the Lambert W_-1 function is

actually the inverse of the Lambert W₀ function. Which
could also be easily calculated as x e^x.

W_-1 is not so easily calculated. So would be more useful
to have on the calc.

Easily done on the HP-12C:

01 CHS               

02 1/x               

03 STO 0              

04 STO 1              

05 LN                

06 RCL 0             

07 *                 

08 RCL 1             

09 x<>y               

10 -                 

11 x=0                

12 GTO 15            

13 LST x             

14 GTO 04            

15 LST x             

16 RCL 0             

17 /                  

18 CHS                

19 GTO 00           

-0.2  R/S ->   -2.542641358  

Edited: 25 Nov 2011, 10:54 a.m.

Just in case it's useful, functions WL1 and WL0 are available in the SandMath-II module for the HP-41, both implemented in MCODE.

The module is available at TOS for V41 and i41CX usage - also possible to burn into Clonix, MLDL2k, etc. of course.

Cheers,
ÁM

Edited: 25 Nov 2011, 10:49 a.m.

It would be easy enough to include a user code programme to calculate this branch of the W function in the device -- for real arguments only. I'd guess 100 or so bytes of precious flash.

Alternatively, use this program:

	01  LBL'W[sub-1]'

	02  LocR 02

	03  STO .02

	04  +/-

	05  1/x

	06  STO .00

	07  STO .01

	08  LN

	09  RCL[times] .00

	10  RCL .01

	11  x[<->] Y

	12  -

	13  x=0?

	14  SKIP 03

	15  DROP

	16  RCL L

	17  BACK 10

	18  DROP

	19  RCL L

	20  RCL/ .00

	21  +/-

	22  x[<->] .02

	23  STO L

	24  x[<->] .02

	25  RTN

Store it in one of the flash segments and you've got the W_-1 function. It behaves like a keyboard command in that Last X is set properly and the stack is not damaged. The argument range is not correctly validated however.

- Pauli

Pauli, [sub-1] ??

Yeah, [sub-1] which displays as ₁. We don't have a subscript minus or minus 1. All our codes for subscripts are [sub-X].

The other convention I've seen is W_m and W_p for w_-1 and W₀ respectively.

- Pauli

Exactly. And we feature [sub-m] and [sub-p] ... :-)

I know that was why I mentioned them ;-)

- Pauli

With the next software build, you'll find both branches on the WP 34S: W_p for the principal branch and W_m=W_-1 for the lower branch. The latter is calculated by an XROM routine, so it may not be as accurate as W_p.

Great!