HP Forums

41Notes (HP-41CX or HP-41C/CV with X-Function)

My small contribution to store small notes

01 LBL "41NOTES"

02 "NOTES"

03 RCLPTA

04 FIX 0

05 CF 29

06 LBL 52

07 CF 21

08 "A:F:I:P:V?   " '3 spaces

09 ASROOM

10 ARCL X

11 AVIEW

12 GETKEY

13 X=0?

14 GTO 15

15 CLD

16 XEQ IND X

17 GTO 52

18 LBL 11

19 CLA

20 AON

21 PROMPT

22 AOFF

23 APPREC

24 RTN

25 LBL 24

26 SF 25

27 "NOTES"

28 20 ' Modify for large number of notes

29 PURFL

30 CRFLAS

31 RTN

32 LBL 15

33 CLD

34 FIX 2

35 STOP

36 LBL 62

37 CLX

38 SEEKPT

39 SF 25

40 LBL 61

41 GETREC

42 AVIEW

43 PSE

44 "-:+:D:R:S?"

45 FC? 25

46 GTO 52

47 AVIEW

48 GETKEY

49 X=0?

50 GTO 52

51 XEQ IND X

52 GTO 61

53 LBL 51

54 CLX

55 SEEKPT

56 RCLPT

57 INT

58 1

59 -

60 SEEKPT

61 RTN

62 LBL 14

63 DELREC

64 RTN

65 LBL 43

66 SF 21

67 CLX

68 SEEKPT

69 SF 25

70 LBL 00

71 GETREC

72 FC? 25

73 RTN

74 AVIEW

75 GTO 00

76 LBL 53

77 "SRC?"

78 AON

79 PROMPT

80 AOFF

81 CLX

82 SEEKPT

83 POSFL

84 INT

85 SEEKPT

86 END

Instructions

XEQ "41NOTES"

First time: press I 'Initialize "NOTES" file in X-Memory

Option

A ' Add Notes (Max 24 bytes) R/S

E ' End

I ' Initialize (First time or Clear all Notes !!!)

P ' Print or View Records

V ' View ------ + ' Next Record

		- ' Previous Record

		D ' Delete Present Record

		R ' Return

S ' Search a string

* In the main menu if there is not any key pressed in 10 seconds the program concludes.

* In the visualization way if there is not any key pressed in 10 seconds returns for the main menu

For the usual VIM 41 syntax/ftplugin compatability:
(also corrected an error in line 008, the "F" in the original should read "E")

001 *LBL'41NOTES

002  'NOTES

003  RCLPTA

004  FIX 0

005  CF 29

006  LBL 52

007  CF 21

008  'A:E:I:P:V?   " '3 spaces

009  ASROOM

010  ARCL X

011  AVIEW

012  GETKEY

013  X=0?

014  GTO 15

015  CLD

016  XEQ IND X

017  GTO 52

018  LBL 11

019  CLA

020  AON

021  PROMPT

022  AOFF

023  APPREC

024  RTN

025  LBL 24

026  SF 25

027  'NOTES

028  20 ' Modify for large number of notes

029  PURFL

030  CRFLAS

031  RTN

032  LBL 15

033  CLD

034  FIX 2

035  STOP

036  LBL 62

037  CLX

038  SEEKPT

039  SF 25

040  LBL 61

041  GETREC

042  AVIEW

043  PSE

044  '-:+:D:R:S?

045  FC? 25

046  GTO 52

047  AVIEW

048  GETKEY

049  X=0?

050  GTO 52

051  XEQ IND X

052  GTO 61

053  LBL 51

054  CLX

055  SEEKPT

056  RCLPT

057  INT

058  1

059  -

060  SEEKPT

061  RTN

062  LBL 14

063  DELREC

064  RTN

065  LBL 43

066  SF 21

067  CLX

068  SEEKPT

069  SF 25

070  LBL 00

071  GETREC

072  FC? 25

073  RTN

074  AVIEW

075  GTO 00

076  LBL 53

077  'SRC?

078  AON

079  PROMPT

080  AOFF

081  CLX

082  SEEKPT

083  POSFL

084  INT

085  SEEKPT

086  END

Edited: 12 Nov 2005, 4:20 p.m.

Maybe do this at the start?

002  SF 25

003  'NOTES

004  RCLPTA

005  FC?C 25

006  XEQ 24

I thank for the line 8: -) 

To create the File Notes 

'NOTES' <--- Alpha

20

CRFLAS

or

002  SF 25

003  'NOTES

004  RCLPTA

005  FC?C 25

006  XEQ 24