HP Forums

CATALOG ( 1196 bytes)
11/12/11  14:48:43

1 DELAY 0 @ B=1 @ I=1 @ A$(1)="1:75" @ A$(2)="2:Xmem" @ A$(3)="3:DR"

2 IF B=1 THEN A$=CAT$(I)

3 IF B=2 THEN A$=XCAT$(I)

4 IF B=3 THEN A$=TCAT$(':dr',I)

5 IF A$="" THEN I=I-1 @ GOTO 2 ELSE DISP A$

6 B$=WKEY$ @ IF B$="…" THEN I=I+1

7 IF B$="„" AND I-1#0 THEN I=I-1 @ GOTO 2

8 IF B$='u' THEN C$="Purge" @ GOSUB 16 @ PURGE A$ @ GOTO 1

9 IF B$='e' AND A$[12,12]="B" THEN C$="Edit" @ GOSUB 16 @ EDIT A$ @ END

10 IF B$='r' AND A$[12,12]="B" THEN C$="Run" @ GOSUB 16 @ RUN A$

11 IF B$='c' THEN C$="Copy to drive " @ GOSUB 16 @ GOTO 21

12 IF B$="x" THEN B=GETMSG("1:75 2:Xmem 3:DR ?","123") @ I=1 @ GOTO 2

13 IF B$="b" THEN BYE

14 IF B$='p' THEN C$="Print" @ D$=A$ @ GOSUB 16 @ GOTO 18

15 GOTO 2

16 A$=A$[1,POS(A$," ")-1]

17 A=GETMSG(A$&" "&C$&"? [YN]:","yn") @ IF A=2 THEN GOTO 2 ELSE DISP CHR$(27);"J" @ RETURN

18 PWIDTH INF @ PRINT A$;' (';VAL(D$[13,18]);'bytes)'

19 PRINT @ B$=DATE$ @ PRINT B$[7,8]&B$[3,6]&B$[1,2]&"  "&TIME$ @ PRINT

20 PLIST A$ @ PRINT @ GOTO 2

21 D$=" or " @ IF B=1 THEN B$=A$(2)&D$&A$(3)

22 IF B=2 THEN B$=A$(1)&D$&A$(3)

23 IF B=3 THEN B$=A$(1)&D$&A$(2)

24 DISP C$[1,8]&B$&" ?" @ B=VAL(WKEY$) @ B$=A$ @ IF B#1 THEN B$=A$(B)[2,LEN(A$(B))]

25 IF A$="keys" THEN COPY KEYS TO B$ ELSE COPY A$ TO B$

26 GOTO 2

u    = Purge File

e    = Edit Basic File

r    = Run Basic File

c    = Copy File to

p    = Print Basic File

b    = Bye (Off)

Up   = Next File

Down = Previous File 

KEYLEX75 - UNLOCK

	 - SHLOCK

	 - CTLOCK

	 - GETMSG($,$)

	 - GETKEY$($)

	 - WKEY$

:Xmem=82718A

Enjoy :-)
robertoataulfo
